option explicit

Function OnInit(initData)
	initData.name = "ColonneNiveau"
	initData.desc = "Ajoute une colonne 'Niveau' pour afficher la profondeur des dossiers."
	initData.copyright = "2014 Albator V (Michiels Thomas)"
	initData.min_version = "11.6.1"	
	initData.version = "v3.0"
	initData.default_enable = false
	initData.config.PremierNiveau = "1" 			'Choose 1st level value
'	initData.config._descriptions = DOpus.NewMap("PremierNiveau", "Description about this item")
	initData.config.Decalage = false 				'Display indent
	initData.config.DecalageSeparateur = ".." 		'Choose indent character
End Function

Function OnScriptConfigChange(configChangeData)
	Script.InitColumns
End Function

Function OnAddColumns(addColData)
	Dim col: Set col = addColData.AddColumn
	col.name = "Niveau"
	col.method = "OnNiveau"
	col.label = "Niveau"
	col.header = "##"
	col.nogroup = true
	If script.config.Decalage = false then
		col.justify = "right"
	Else
		col.justify = "left"
	End If
End Function

Function OnNiveau(scriptColData)
	Dim Niveau: Niveau = (Ubound(Split(Replace(scriptColData.item.realpath, scriptColData.tab.path, ""),"\"))) + (script.config.PremierNiveau - 1)
	If script.config.Decalage = true then
		Dim i, Dec
		For i = script.config.PremierNiveau to Niveau - 1
			Dec = Dec & script.config.DecalageSeparateur
		Next
	End If	
	scriptColData.value = Dec & Niveau
End Function