Option Explicit

Function OnInit(initData)
	initData.name = "Commande_AddCoverartFromClipboard"
	initData.desc = "Ajoute les fichiers image du presse papier comme pochette d'un mp3."
	initData.min_version = "11.12"
	initData.copyright = "2015 Albator V (Michiels Thomas)"
	initData.version = "v1.0"
	initData.default_enable = true
	initData.config.EffacerJournal = false
	initData.config.InscriptionJournal = false
	initData.config_desc = Dopus.Create.Map("EffacerJournal", "Effacer le journal au lancement de la commande.", _
											"InscriptionJournal", "Afficher les messages dans le journal.")
End Function


Function OnAddCommands(addCmdData)
	Dim cmd: Set cmd = addCmdData.AddCommand()
	cmd.name = "AddCoverartFromClipboard"
	cmd.method = "OnAddCoverartFromClipboard"
	cmd.desc = "Ajoute les fichiers image du presse papier comme pochette d'un mp3"
	cmd.label = "AddCoverartFromClipboard"
	cmd.icon = "imageshack"
	cmd.template = "DESELECT/S"
End Function

Function OnAddCoverartFromClipboard(funcData)

	Dim strClip
	Dim objClipFiles
	Dim strClipArrayJpg
	Dim ImageFile
	
' Clear log
	If script.config.EffacerJournal = True Then Dopus.clearOutput

' Find image in clipboard
	If DOpus.GetClipFormat() = "files" Then
		Set objClipFiles = DOpus.GetClip("files")
		strClipArrayJpg = Empty
		
		For Each ImageFile In objClipFiles
			If ImageFile.display_name <> "" Then
				strClip = ImageFile.path & "\" & ImageFile.display_name
			Else
				strClip = ImageFile.path & "\" & ImageFile.name
			End If
			
			If Right(strClip,3)="jpg" Then
				If IsEmpty(strClipArrayJpg) Then
					ReDim strClipArrayJpg(0)
				Else
					ReDim Preserve strClipArrayJpg(UBound(strClipArrayJpg)+1)
				End If
				strClipArrayJpg(UBound(strClipArrayJpg)) = strClip
			End If
		Next
	End If

' Add image to selection
	If IsEmpty(strClipArrayJpg) Then
		If script.config.InscriptionJournal = True Then DOpus.OutputString "Alerte: Aucun fichier image dans le presse papier."
	Else
		If script.config.InscriptionJournal = True Then Dopus.OutputString "Information: " & UBound(strClipArrayJpg)+1 & " fichier(s) image dans le presse papier."
		For Each ImageFile In strClipArrayJpg
'			If script.config.InscriptionJournal = True Then Dopus.OutputString "Fichier image du presse papier: " & ImageFile
			If script.config.InscriptionJournal = True Then Dopus.OutputString "Commande envoyée: " & "SetAttr META ""coverart:+3:" & ImageFile & """"
			funcData.Func.Command.RunCommand "SetAttr META ""coverart:+3:" & ImageFile & """"
		Next
	End If

' Look if argument exists
	If funcData.func.args.got_arg.deselect = 1 Then funcData.func.command.RunCommand("Select NONE")

End Function