option explicit

Dim strYes, strNo
strYes = "Yes"
strNo = "No"

Function OnInit(initData)
	initData.name = "Icaros video columns"
	initData.version = "1.1"
	initData.copyright = "(c) 2019-2021 Leo Davidson"
	initData.url = "https://resource.dopus.com/t/icaros-video-information-columns/32513"
	initData.desc = "Import columns added by the Icaros shell extension into Opus (requires Icaros is installed and Properties enabled in its config window)"
	initData.default_enable = true
	initData.min_version = "12.14"

	Dim props, prop, col
	Set props = DOpus.FSUtil.GetShellPropertyList("Icaros.*", "r")
	For each prop in props
		Set col = initData.AddColumn
		col.name = prop.raw_name
		col.method = "OnIcarosColumn"
		col.label = prop.display_name
		col.justify = "left"
		col.autogroup = true
		col.userdata = prop.pkey
		If prop.raw_name = "Icaros.ContainsChapters" Then
			col.match.push_back strYes
			col.match.push_back strNo
		End If
	Next
End Function

Function OnIcarosColumn(scriptColData)

	scriptColData.value = scriptColData.item.shellprop(scriptColData.userdata)

	If scriptColData.col = "Icaros.ContainsChapters" And Not IsEmpty(scriptColData.value) Then
		If scriptColData.value = -1 Then
			scriptColData.value = strYes
		Else
			scriptColData.value = strNo
		End If
	End If

End Function