Currently we have 'today only' and 'all days for the past week'. It would be nice if you add 'today + yesterday' in between 
1 Like
In the meantime, you could use an Eval Column:
XML
<?xml version="1.0"?>
<evalcolumn align="1" attrrefresh="yes" autorefresh="yes" category="date" foldertype="all" header="Modified" keyword="modifiedfriendly" maxstars="5" namerefresh="no" reversesort="no" title="Modified (friendly+)" type="7">yesterday = Now() - 60*60*24;
if (DatePart(modified, "date") == DatePart(Now(), "date")) return "Today " + DatePart(modified, "time");
if (DatePart(modified, "date") == DatePart(yesterday, "date")) return "Yesterday " + DatePart(modified, "time");
return modified;</evalcolumn>
4 Likes
It's a global setting.
It's there, it's just incorrectly showing as "Modified" instead of "Modified (friendly+)". Fixed in the next beta.
Finally got to try this trick, nice one!
Faced a few problems/questions however:
- Sorting - the column is being sorted like a text (in alphabetic order), not like a date/time. Is there something we can do about it or is it a bug?
- Grouping is inappropriate as well.
- Any translations for the text should be done manually or is there a reliable & easy way to implement them?
Overall I still believe a new dedicated option for 'Friendly Dates' would just be better 
What's interesting is how it's so obvious and easy feature but not in the list from the beginning 
Yes, both is possible. Check out the built-in eval column Modified (simple) (updated in 13.2.1) for details.
'Modified (simple)' column is broken as well in terms of sorting and grouping. Or maybe I'm having an outdated version of it?
<?xml version="1.0"?>
<evalcolumn align="1" attrrefresh="yes" autorefresh="yes" category="date" customgrouping="no" foldertype="all" header="Modified" keyword="modifiedsimple" maxstars="5" namerefresh="no" reversesort="yes" title="Modified (simple)" type="0">if (DatePart(modified, "date") == DatePart(Now(), "date"))
return DatePart(modified, "time");
return DatePart(modified, "date");</evalcolumn>
Current definition is this:
// sort by modified date
if (operation == "sort")
return modified;
// today?
today = Now();
mod_date = DatePart(modified, "date");
if (mod_date == DatePart(today, "date"))
{
if (operation == "group")
return LanguageStr(2195); // today
return DatePart(modified, "time");
}
// if grouping, work out how old
if (operation == "group")
{
if (modified > today)
return LanguageStr(5793); // future
mod_year = DatePart(modified, "yyyy");
today_year = DatePart(today, "yyyy");
if (mod_year == today_year)
return LanguageStr(5800); // earlier this year
if (mod_year == today_year - 1)
return LanguageStr(5801); // last year
return LanguageStr(5802); // a long time ago
}
return mod_date;
1 Like
Thanks! Pasting here an updated version of 'Modified (friendly+)' column:
<?xml version="1.0"?>
<evalcolumn align="1" attrrefresh="yes" autorefresh="yes" category="date" customgrouping="yes" foldertype="all" header="Modified" keyword="modifiedfriendlyplus" maxstars="5" namerefresh="no" reversesort="yes" title="Modified (friendly+)" type="7">if (operation != "sort")
{
today = Now();
yesterday = today - 60 * 60 * 24;
mod_date = DatePart(modified, "date");
if (mod_date == DatePart(today, "date"))
{
today_str = LanguageStr(2195); // or 5794 // "Today"
if (operation == "group")
return "1. " + today_str;
return today_str + " " + DatePart(modified, "time");
}
if (mod_date == DatePart(yesterday, "date"))
{
yesterday_str = LanguageStr(2196); // or 5795 // "Yesterday"
if (operation == "group")
return "2. " + yesterday_str;
return yesterday_str + " " + DatePart(modified, "time");
}
if (operation == "group")
{
if (modified > today)
return "0. " + LanguageStr(5793); // "Future"
mod_year = DatePart(modified, "yyyy") as int;
today_year = DatePart(today, "yyyy") as int;
//Output("mod_year = " + mod_year + "; today_year = " + today_year);
if (mod_year == today_year)
{
mod_month = DatePart(modified, "M") as int;
today_month = DatePart(today, "M") as int;
//Output("mod_month = " + mod_month + "; today_month = " + today_month);
if (mod_month == today_month)
{
mod_week = DatePart(modified, "w") as int;
today_week = DatePart(today, "w") as int;
//Output("mod_week = " + mod_week + "; today_week = " + today_week);
if (mod_week == today_week)
return "3. " + LanguageStr(5796); // "Earlier this week"
if (mod_week == (today_week - 1))
return "4. " + LanguageStr(5797); // "Last week"
return "5. " + LanguageStr(5798); // "Earlier this month"
}
if (mod_month == (today_month - 1)) // Note: If today's month is January, and Modified's is December, code will take "Last year" path, not this one. Should be changed?
return "6. " + LanguageStr(5799); // "Last month"
return "7. " + LanguageStr(5800); // "Earlier this year"
}
if (mod_year == (today_year - 1))
return "8. " + LanguageStr(5801); // "Last year"
return "9. " + LanguageStr(5802); // "A long time ago"
}
}
return modified;
</evalcolumn>
Update1: Made group names numbered so that they can be sorted in a deterministic order (by actual age), not in alphabetic order.
Update2: Added explicit type casting and parenthesis, that fixed wrong grouping in my tests.
Bug ? My paste icon is not activating when copying the above xml.
nvm. was trying to paste it into Evaluator Groups, it pastes OK into Evaluator Columns.
Okay, updated it further. Now the code is splitted between EvalColumn (displaying of data) and EvalGroup (grouping of data):
column.xml
<?xml version="1.0"?>
<evalcolumn align="1" attrrefresh="yes" autorefresh="yes" category="date" customgrouping="yes" foldertype="all" header="Modified" keyword="modifiedfriendlyplus" maxstars="5" namerefresh="no" reversesort="yes" title="Modified (friendly+)" type="7">if (operation == "display")
{
today = Now();
mod_date = DatePart(modified, "date");
if (mod_date == DatePart(today, "date"))
return LanguageStr(5794) + " " + DatePart(modified, "time"); // "Today"
yesterday = today - 60 * 60 * 24;
if (mod_date == DatePart(yesterday, "date"))
return LanguageStr(5795) + " " + DatePart(modified, "time"); // "Yesterday"
}
return modified;
</evalcolumn>
group_scheme.xml
<?xml version="1.0"?>
<evalgroupscheme desc=""Modified (friendly+)" group scheme" reverse="yes" scheme_name="modifiedfriendlyplus_group" sort="no">
<eval>today = Now();
if (value > today)
return [ name = LanguageStr(5793); order = value; ]; // "Future"
mod_date = DatePart(value, "date");
if (mod_date == DatePart(today, "date"))
return [ name = LanguageStr(5794); order = value; ]; // "Today"
yesterday = today - 60 * 60 * 24;
if (mod_date == DatePart(yesterday, "date"))
return [ name = LanguageStr(5795); order = value; ]; // "Yesterday"
mod_year = DatePart(value, "yyyy") as int;
today_year = DatePart(today, "yyyy") as int;
//Output("mod_year = " + mod_year + "; today_year = " + today_year);
if (mod_year == today_year)
{
mod_month = DatePart(value, "M") as int;
today_month = DatePart(today, "M") as int;
//Output("mod_month = " + mod_month + "; today_month = " + today_month);
if (mod_month == today_month)
{
mod_week = DatePart(value, "w") as int;
today_week = DatePart(today, "w") as int;
//Output("mod_week = " + mod_week + "; today_week = " + today_week);
if (mod_week == today_week)
return [ name = LanguageStr(5796); order = value; ]; // "Earlier this week"
if (mod_week == (today_week - 1))
return [ name = LanguageStr(5797); order = value; ]; // "Last week"
return [ name = LanguageStr(5798); order = value; ]; // "Earlier this month"
}
if (mod_month == (today_month - 1)) // Note: If today's month is January, and value's is December, code will take "Last year" path, not this one. Should be changed?
return [ name = LanguageStr(5799); order = value; ]; // "Last month"
return [ name = LanguageStr(5800); order = value; ]; // "Earlier this year"
}
if (mod_year == (today_year - 1))
return [ name = LanguageStr(5801); order = value; ]; // "Last year"
return [ name = LanguageStr(5802); order = value; ]; // "A long time ago"
</eval>
<groups enable="no" />
<columns />
</evalgroupscheme>
Now we have correct group sorting with clean group names (no more numbers before text).
P.S. This could be done a bit easier if EvalColumn supported directly specifying group order in itself, upvote this feature request if you agree